Spring’s @Primary annotation in action

PersonProcessingServiceContainer.java

package com.blogspot.toomuchcoding.person.service;

import java.util.ArrayList;
import java.util.List;

import org.apache.commons.lang.StringUtils;
import org.slf4j.Logger;
import org.slf4j.LoggerFactory;
import org.springframework.beans.factory.annotation.Autowired;
import org.springframework.context.annotation.Primary;
import org.springframework.stereotype.Component;

import com.blogspot.toomuchcoding.person.domain.Person;

@Component
@Primary
class PersonProcessingServiceContainer implements PersonProcessingService {

 private static final Logger LOGGER = LoggerFactory.getLogger(PersonProcessingServiceContainer.class);
 
 @Autowired
 private List<PersonProcessingService> personProcessingServices = new ArrayList<PersonProcessingService>();
 
 @Override
 public boolean isApplicableFor(Person person) {
  return person != null;
 }

 @Override
 public String process(Person person) {
  List<String> output = new ArrayList<String>();
  for(PersonProcessingService personProcessingService : personProcessingServices){
   if(personProcessingService.isApplicableFor(person)){
    output.add(personProcessingService.process(person));
   }
  }
  String result = StringUtils.join(output, ",");
  LOGGER.info(result);
  return result;
 }

 public List<PersonProcessingService> getPersonProcessingServices() {
  return personProcessingServices;
 }
}

As you can see we have a container that is annotated with @Primary which means that if an implementation of the PersonProcessingService will have to be injected then Spring will pick the PersonProcessingServiceContainer to be injected. The cool thing is that we have an autowired list of PersonProcessingServices which means that all other implementations of that interface will get autowired there (the container will not autowire itself to the list!).

Now let’s check out the Spock tests that prove that I’m not telling any lies. If you aren’t using Spock already in your project then you should move it straight away 🙂

PersonProcessingServiceContainerIntegrationSpec.groovy

package com.blogspot.toomuchcoding.person.service
import com.blogspot.toomuchcoding.configuration.SpringConfiguration
import com.blogspot.toomuchcoding.person.domain.Person
import org.springframework.beans.factory.annotation.Autowired
import org.springframework.test.context.ContextConfiguration
import spock.lang.Specification
import spock.lang.Unroll

import static org.hamcrest.CoreMatchers.notNullValue

@ContextConfiguration(classes = [SpringConfiguration])
class PersonProcessingServiceContainerIntegrationSpec extends Specification {

    @Autowired
    PersonProcessingService personProcessingService
    
    def "should autowire container even though there are many implementations of service"(){       
        expect: 
            personProcessingService instanceof PersonProcessingServiceContainer
    }
    
    def "the autowired container should not have itself in the list of autowired services"(){       
        expect: 
            personProcessingService instanceof PersonProcessingServiceContainer
        and:
            !(personProcessingService as PersonProcessingServiceContainer).personProcessingServices.findResult {
                it instanceof PersonProcessingServiceContainer
            }
    }
    
    def "should not be applicable for processing if a person doesn't exist"(){
        given:
            Person person = null
        expect:
            !personProcessingService.isApplicableFor(person)
    }
    
    def "should return an empty result for a person not applicable for anything"(){
        given:
            Person person = new Person("", 17, false)
        when:
            def result = personProcessingService.process(person)
        then:
            result notNullValue()
            result.isEmpty()
    }

    @Unroll("For name [#name], age [#age] and being stupid [#stupid] the result should contain keywords #keywords")
    def "should perform different processing depending on input"(){
        given:
            Person person = new Person(name, age, stupid)
        when:
            def result = personProcessingService.process(person)        
        then:
            keywords.every {
                result.contains(it)    
            }
        where:
            name  | age | stupid || keywords
            "jan" | 20  | true   || ['NAME', 'AGE', 'STUPID']
            ""    | 20  | true   || ['AGE', 'STUPID']
            ""    | 20  | false  || ['AGE']
            null  | 17  | true   || ['STUPID']
            "jan" | 17  | true   || ['NAME']
    }
}

1. We prove that the autowired field is in fact our container – the PersonProcessingServiceContainer.
2. Then we show that we can’t find an object in the collection of autowired implementations of the PersonProcessingService, that is of PersonProcessingServiceContainer type
3. In the next two tests we prove that the logic behind our processors is working
4. Last but not least is the Spock’s finest – the where clause that allows us create beautiful paramterized tests.

Per module feature

@Component
class CoreModuleClass implements SomeInterface {
...
}

@Component
@Primary
class CountryModuleClass implements SomeInterface {
...
}